Mplus—交叉滞后面板模型（Cross-Lagged Panel Model, CLPM）

目录

理论篇

CLPM估计三种类型的关系

CLPM的优缺点

操作篇—Mplus语法

显变量模型—两个变量两波数据

结果解读

1. 模型拟合情况

2. 路径系数及显著性

3. 置信区间

4. 修正指数

5. 模型图

显变量模型—三个变量三波数据

中介效应检验语法

显变量模型—三个变量两波数据

潜变量模型

控制协变量

本文介绍交叉滞后模型相关知识，以及显变量模型与潜变量模型在Mplus中的语法。

如仅想了解操作方法，可直接跳转操作篇。

理论篇

交叉滞后面板模型（Cross-Lagged Panel Model, CLPM）是描述变量之间相互关系的一种纵向数据分析方法。

Cross-lagged panel analysis is an analytical strategy used to describe reciprocal relationships, or directional influences, between variables over time (Kearney, 2017).
The cross-lagged panel model (CLPM) has been extremely popular in behavioral and psychological science research (Usami et al., 2019).

最基本的CLPM如下图所示，对两个变量在两个时间点分别进行了测量，因此，该模型包括了两个X变量（x1，x2）和两个Y变量（y1，y2）。

CLPM估计三种类型的关系

1.[Synchronous] Correlations：指同一时间点两个变量之间的关系。在上图中为x1与y1之间的相关（rx1y1），x2与y2之间的相关（rx2y2）。

2.Autoregressive effects：指不同时间点同一变量之间的关系。在上图中为x1到x2的效应（β3），y1到y2的效应（β4）。

Autoregressive effects describe the amount of stability in constructs over time. Smaller autoregressive coefficients (closer to zero) indicate more variance in the construct, meaning less stability or influence from the previous time point. Larger autoregressive coefficients indicate little variance over time, meaning more stability or influence from the previous time point (Kearney, 2017).

3.Cross-Lagged effects：指不同时间点不同变量之间的关系。在上图中为x1到y2的效应（β1），y1到x2的效应（β2）。

CLPM的优缺点

CLPM的优点为：在控制同一时间点内变量之间相关性和变量跨时间稳定性的情况下，探讨一个变量对另一个变量的预测效应。

CLPM的缺点是：纵向数据本身是一种多水平的数据，变量变异的来源可以天然分类到个体间水平和个体内水平。但CLPM混淆了个体间（Between-person）和个体内（Within-person）这两个截然不同水平的效应。

A major limitation of the CLPM is that it does not separate between-person effects from within-person effects. Depending on the between-person and within-person variance structures, CLPM results may reflect mostly between-person effects, mostly within-person effects, or an ambiguous mix of effects, leaving the researcher with an uninterpretable blend of effects (Masselink et al., 2018).

因此，传统交叉滞后模型的基础上，Hamaker等人（2015）提出了随机截距的交叉滞后模型（Random Intercepts Cross-Lagged Panel Model, RI-CLPM），详情可见下面这篇文章。

随机截距交叉滞后模型（Random Intercepts Cross-Lagged Panel Model, RI-CLPM）_Kunle~的博客-CSDN博客https://blog.csdn.net/m0_54401011/article/details/129029691

操作篇—Mplus语法

显变量模型—两个变量两波数据

假设有两个变量X和Y，对每个变量进行了两次测量，得到四个变量x1，x2，y1，y2。对应CLPM的Mplus语句为：

TITLE: Cross-Lagged Panel Model, 2 variables, 2 waves;

DATA: FILE IS 123.dat; ! 数据来源

VARIABLE: NAME ARE x1 x2 y1 y2; ! 变量名称

MISSING=ALL(99); ! 定义缺失值

USEVARIABLE ARE x1 x2 y1 y2; ! 使用变量

ANALYSIS: ESTIMATOR=MLR; ! 估计方法，可以自己数据特点而选取

MODEL: x2 y2 ON x1; ! x1指向x2和y2

x2 y2 ON y1; ! y1指向x2和y2

x1 WITH y1; ! 同一时间点两个量表之间的相关

x2 WITH y2;

OUTPUT: SAMPSTAT STDYX MOD CINTERVAL; ! 输出样本统计量、标准化值、修正指数、置信区间等值

结果解读

1. 模型拟合情况

该模型为饱和模型，因此没有必要报告模型拟合情况。

但其他模型，可以依据文献，选取指标，对模型的优劣进行评价。

2. 路径系数及显著性

下图为非标准化模型结果。

由图可知，该模型中自回归路径系数显著、交叉滞后路径显著、同一时间点不同变量之间的相关也显著。

下图为标准化模型结果。

3. 置信区间

4. 修正指数

5. 模型图

如果想比较x1到y2的路径系数和y1到x2的路径系数大小/是否存在显著差异，可参考下面这篇文章。

Mplus—路径系数差异比较 – 知乎 (zhihu.com)https://zhuanlan.zhihu.com/p/596519117

显变量模型—三个变量三波数据

假设自变量为X，中介变量为M，因变量为Y

对每个变量进行了两次测量，得到六个变量x1，x2，x3，m1，m2，m3，y1，y2，y3。对应CLPM的Mlpus语句为：

TITLE: Cross-Lagged Panel Model, 3 variables, 3 waves;

DATA: FILE IS 123.dat; ! 数据来源

VARIABLE: NAME ARE x1 x2 x3 m1 m2 m3 y1 y2 y3; ! 变量名称

MISSING=ALL(99); ! 定义缺失值

USEVARIABLE ARE x1 x2 x3 m1 m2 m3 y1 y2 y3; ! 使用变量

ANALYSIS: ESTIMATOR=MLR; ! 估计方法，可以自己数据特点而选取

MODEL: x2 m2 y2 ON x1;

x2 m2 y2 ON m1;

x2 m2 y2 ON y1;

x3 m3 y3 ON x2;

x3 m3 y3 ON m2;

x3 m3 y3 ON y2;

x1 WITH m1 y1;

m1 WITH y1;

x2 WITH m2 y2;

m2 WITH y2;

x3 WITH m3 y3;

m3 WITH y3;

OUTPUT: SAMPSTAT STDYX MOD CINTERVAL;

中介效应检验语法

TITLE: CROSS-LAGGED PANEL MODEL;

DATA: FILE IS 123.dat; ! 数据来源

VARIABLE: NAME ARE x1 x2 x3 m1 m2 m3 y1 y2 y3; ! 变量名称

MISSING=ALL(99); ! 定义缺失值

USEVARIABLE ARE x1 x2 x3 m1 m2 m3 y1 y2 y3; ! 使用变量

ANALYSIS: BOOTSTRAP=2000; ! 使用Bootstrap法进行中介效应检验，抽样次数1000或2000或5000，有文献依据即可

MODEL: x2 m2 y2 ON x1;

x2 m2 y2 ON m1;

x2 m2 y2 ON y1;

x3 m3 y3 ON x2;

x3 m3 y3 ON m2;

x3 m3 y3 ON y2;

x1 WITH m1 y1;

m1 WITH y1;

x2 WITH m2 y2;

m2 WITH y2;

x3 WITH m3 y3;

m3 WITH y3;

MODEL INDIRECT: y3 IND m2 x1;

OUTPUT: SAMPSTAT STDYX CINTERVAL;

显变量模型—三个变量两波数据

假设自变量为X，中介变量为M，因变量为Y

对每个变量进行了两次测量，得到六个变量x1，x2，m1，m2，y1，y2。对应CLPM的语句为：

TITLE: Cross-Lagged Panel Model, 3 variables, 2 waves;

DATA: FILE IS 12.dat; ! 数据来源

VARIABLE: NAME ARE x1 x2 m1 m2 y1 y2; ! 变量名称

MISSING=ALL(99); ! 定义缺失值

USEVARIABLE ARE x1 x2 m1 m2 y1 y2;

ANALYSIS: ESTIMATOR=MLR; ! 估计方法

MODEL: x2 m2 y2 ON x1;

x2 m2 y2 ON m1;

x2 m2 y2 ON y1;

x1 WITH m1 y1;

m1 WITH y1;

x2 WITH m2 y2;

m2 WITH y2;

OUTPUT: SAMPSTAT STDYX MOD CINTERVAL;

中介因素的体验，通过选取变量建立中介模型来实现。

在下面两篇文章中，三个变量两个时间点的做法都是先建立交叉滞后模型，然后选取变量做中介模型。

Wang, Y. J., & Xia, L. X. (2019). The longitudinal relationships of interpersonal openness trait, hostility, and hostile attribution bias. Aggressive Behavior, 45(6), 682-690. doi: 10.1002/ab.21862
Su, S., Quan, F., & Xia, L. X. (2021). Longitudinal relationships among interpersonal openness trait, hostile attribution bias, and displaced aggressive behaviour: Big Five treated as covariates. International Journal of Psychology, 56(5), 669-678. doi: 10.1002/ijop.12745

1. 选取第一个时间点的自变量、第一个时间点的中介变量、第二个时间点的因变量建立中介模型，以检验中介变量的效应。

2. 选取第一个时间点的自变量、第二个时间点的中介变量、第二个时间点的因变量建立中介模型，以检验中介变量的效应。

例如，下面这篇文章，根据已有理论和实证研究提出，暴力暴露（Violence Exposure）、敌意自动思维（Hostile Automatic Thoughts）、网络攻击（Cyber‐aggression）之间存在循环关系，因此，首先通过交叉滞后模型探讨变量两两之间的相互预测关系；其次，通过六个中介模型，来检验一个变量在其他两个变量之间的中介作用。

Zhu, W., Sun, L., Lu, D., Li, C., & Tian, X. (2022). The longitudinal relation between violence exposure in daily life, hostile automatic thoughts, and cyber-aggression. Aggressive behavior.https://doi.org/10.1002/ab.22058This study first adopts a cross‐lagged model to test the cyclical relation between violence exposure in daily life, hostile automatic thoughts, and cyber‐aggression. Moreover, we further explore whether each of them is a mediator of the association between the other two variables using six longitudinal mediation models.
Third, the cross‐lagged model was adopted to explore the longitudinal relation among violence exposure, hostile automatic thoughts, and cyber‐aggression. Fourth, structural equation model was used to examine whether hostile automatic thoughts mediated the influence of violence exposure (T1) in daily life on cyber‐aggression (T2) (Model 1) as well as the influence of cyber‐aggression (T1) on violence exposure (T2) (Model 2); whether violence exposure mediated the influence of hostile automatic thoughts (T1) on cyber-aggression (T2) (Model 3) as well as the influence of cyber‐aggression (T1) on hostile automatic thoughts (T2) (Model 4); whether cyber‐aggression mediated the influence of violence exposure (T1) on hostile automatic thoughts (T2) (Model 5) as well as the influence of hostile automatic thoughts (T1) on violence exposure (T2) (Model 6). In the current survey, these variables were only measured in two time point. Theoretically a change of the mediator was expected to precede the changes of the dependent variables. Therefore, the average scores of the mediators at the T1 and T1 was used in these models (Anderson et al., 2007).

潜变量模型

与显变量模型不同之处为，潜变量模型通过BY创建潜变量。

以两个变量两波数据为例，潜变量模型的Mplus语法为：

TITLE: Cross-Lagged Panel Model, 2 variables, 2 waves;

DATA: FILE IS 123.dat; ! 数据来源

VARIABLE: NAME ARE A1-A4 A5-A8 B1-B4 B5-B8; ! 变量名称

MISSING=ALL(99); ! 定义缺失值

USEVARIABLE ARE A1-A4 A5-A8 B1-B4 B5-B8; ! 使用变量

ANALYSIS: ESTIMATOR=MLR; ! 估计方法，可以自己数据特点而选取

MODEL:x1 BY A1-A4;

x2 BY A5-A8;

y1 BY B1-B4;

y2 BY B5-B8; ! 创建潜变量

x2 y2 ON x1; ! x1指向x2和y2

x2 y2 ON y1; ! y1指向x2和y2

x1 WITH y1; ! 同一时间点两个量表之间的相关

x2 WITH y2;

OUTPUT: SAMPSTAT STDYX MOD CINTERVAL; ! 输出样本统计量、标准化值、修正指数、置信区间等值

控制协变量

控制协变量，也就是加入协变量—>研究变量路径的语句。

像性别这样的分类变量，可以将女性编码为0，男性编码为1，然后通过语句：研究变量 ON 性别，来进行控制。

如果是连续变量，直接通过语句：研究变量 ON 控制变量，进行控制。

交叉滞后模型中加入协变量性别的Mplus语法：

TITLE: Cross-Lagged Panel Model, 2 variables, 2 waves;

DATA: FILE IS 12.dat; ! 数据来源

VARIABLE: NAMES ARE gender y1 y2 x1 x2;

MISSING ARE ALL (-99);

USEVARIABLES = gender y1 y2 x1 x2;

MODEL: x2 ON x1 y1;

y2 ON y1 x1;

x1 WITH y1;

x2 WITH y2;

y1 y2 x1 x2 ON gender;

OUTPUT: SAMPSTAT STDYX MOD CINTERVAL;

例如，下面这篇文章，就控制了性别对各个变量的影响。

李芮, 夏凌翔.(2021).攻击动机对特质愤怒与反应性攻击关系的中介作用：一项纵向研究. 心理学报(07),788-797

例如：下面这篇文章，在控制大五人格的基础上，探讨人际开放、敌意归因偏向、替代攻击行为之间的关系。

Su, S., Quan, F., & Xia, L. X. (2021). Longitudinal relationships among interpersonal openness trait, hostile attribution bias, and displaced aggressive behaviour: Big Five treated as covariates. International Journal of Psychology, 56(5), 669-678. doi: 10.1002/ijop.12745

希望上述介绍可以帮助到你！也欢迎大家在评论区多多交流分享。

你的关注/点赞 /收藏★/分享，是最大的支持！